Initial commit

buildSrc/build.gradle.kts

@@ -0,0 +1,10 @@
+plugins {
+    `kotlin-dsl`
+}
+
+dependencies {
+    implementation(libs.gradle.agp)
+    implementation(libs.gradle.kotlin)
+    implementation(libs.gradle.kotlin.serialization)
+    implementation(libs.gradle.kotlinter)
+}

buildSrc/settings.gradle.kts

@@ -0,0 +1,9 @@
+apply(from = "../repositories.gradle.kts")
+
+dependencyResolutionManagement {
+    versionCatalogs {
+        create("libs") {
+            from(files("../gradle/libs.versions.toml"))
+        }
+    }
+}

buildSrc/src/main/kotlin/AndroidConfig.kt

@@ -0,0 +1,8 @@
+object AndroidConfig {
+    const val compileSdk = 32
+    const val minSdk = 21
+    const val targetSdk = 32
+    const val namespace = "eu.kanade.tachiyomi.animeextension"
+    const val coreNamespace = "eu.kanade.tachiyomi.lib.core"
+    const val multisrcNamespace = "eu.kanade.tachiyomi.lib.themesources"
+}

buildSrc/src/main/kotlin/Extensions.kt

@@ -0,0 +1,6 @@
+import org.gradle.api.plugins.ExtensionAware
+import org.gradle.kotlin.dsl.extra
+
+var ExtensionAware.baseVersionCode: Int
+    get() = extra.get("baseVersionCode") as Int
+    set(value) = extra.set("baseVersionCode", value)

buildSrc/src/main/kotlin/lib-android.gradle.kts

@@ -0,0 +1,24 @@
+plugins {
+    id("com.android.library")
+    kotlin("android")
+    id("kotlinx-serialization")
+}
+
+android {
+    compileSdk = AndroidConfig.compileSdk
+
+    defaultConfig {
+        minSdk = AndroidConfig.minSdk
+    }
+
+    namespace = "eu.kanade.tachiyomi.lib.${name.replace("-", "")}"
+}
+
+versionCatalogs
+    .named("libs")
+    .findBundle("common")
+    .ifPresent { common ->
+        dependencies {
+            compileOnly(common)
+        }
+    }

buildSrc/src/main/kotlin/lib-kotlin.gradle.kts

@@ -0,0 +1,13 @@
+plugins {
+    `java-library`
+    kotlin("jvm")
+}
+
+versionCatalogs
+    .named("libs")
+    .findLibrary("kotlin-stdlib")
+    .ifPresent { stdlib ->
+        dependencies {
+            compileOnly(stdlib)
+        }
+    }

buildSrc/src/main/kotlin/lib-multisrc.gradle.kts

@@ -0,0 +1,55 @@
+plugins {
+    id("com.android.library")
+    kotlin("android")
+    id("kotlinx-serialization")
+    id("org.jmailen.kotlinter")
+}
+
+android {
+    compileSdk = AndroidConfig.compileSdk
+
+    defaultConfig {
+        minSdk = AndroidConfig.minSdk
+    }
+
+    namespace = "eu.kanade.tachiyomi.multisrc.${project.name}"
+
+    sourceSets {
+        named("main") {
+            manifest.srcFile("AndroidManifest.xml")
+            java.setSrcDirs(listOf("src"))
+            res.setSrcDirs(listOf("res"))
+            assets.setSrcDirs(listOf("assets"))
+        }
+    }
+
+    buildFeatures {
+        resValues = false
+        shaders = false
+    }
+
+    kotlinOptions {
+        freeCompilerArgs += "-opt-in=kotlinx.serialization.ExperimentalSerializationApi"
+    }
+}
+
+versionCatalogs
+    .named("libs")
+    .findBundle("common")
+    .ifPresent { common ->
+        dependencies {
+            compileOnly(common)
+        }
+    }
+
+tasks {
+    preBuild {
+        dependsOn(lintKotlin)
+    }
+
+    if (System.getenv("CI") != "true") {
+        lintKotlin {
+            dependsOn(formatKotlin)
+        }
+    }
+}